awk 流程控制语句（if,for,while,do)

发表于2012-07-28 作者 admin

同linux 下shell 一样，awk下也有 while、do-while和for 这样的流程控制语句，在for、while、do-while 循环中允许使用break,continue语句来控制流程走向，也允许使用exit这样的语句来退出。break中断当前正在执行的循环并跳到循环外执行下一条语句。



<br />

一、条件判断语句(if)

if(表达式) #if ( Variable in Array )
   语句1
else
   语句2

格式中"语句1"可以是多个语句，如果你为了方便Unix awk判断也方便你自已阅读，你最好将多个语句用{}括起来。Unix awk分枝结构允许嵌套，其格式为：



<br />

if(表达式)
    {语句1}
else if(表达式)
    {语句2}
else
    {语句3}

示例如下：



<br />

[root@361way ~]# awk 'BEGIN{
test=100;
if(test>90)
{
    print "very good";
}
else if(test>60)
{
    print "good";
}
else
{
    print "no pass";
}
}'
very good

每条命令语句后面可以用“；”号结尾。



<br />

二、循环语句(while,for,do)

<br />

1、while语句

while(表达式)
{语句}

示例：



<br />

[root@361way ~]# awk 'BEGIN{
test=100;
total=0;
while(i<=test)
{
    total+=i;
    i++;
}
print total;
}'
5050

<br />

2、for 循环

格式1：
for(变量 in 数组)
{语句}
格式2：
for(变量;条件;表达式)
{语句}

例1：



<br />

# awk 'BEGIN{ for(k in ENVIRON)
  {
    print k"="ENVIRON[k];
   }
}'
TERM=linux
G_BROKEN_FILENAMES=1
SHLVL=1
PWD=/tmp
………………省略

例2：



<br />

# awk 'BEGIN{
total=0;
for(i=0;i<=100;i++)
{
    total+=i;
}
print total;
}'
5050

<br />

3、do循环

格式：

do
{语句}while(条件)

示例：

# awk 'BEGIN{
total=0;
i=0;
do
{
    total+=i;
    i++;
}while(i<=100)
print total;
}'
5050

<br />



以上为awk流程控制语句，从语法上面大家可以看到，与c语言是一样的。有了这些语句，其实很多shell程序都可以交给awk，而且性能是非常快的。



&nbsp;

break	当break语句用于while或for语句时，导致退出程序循环。
continue	当continue 语句用于while或 for 语句时，使程序循环移动到下一个迭代。
next	能能够导致读入下一个输入行，并返回到脚本的顶部。这可以避免对当前输入行执行其他的操作过程。
exit	语句使主输入循环退出并将控制转移到END,如果END存在的话。如果没有定义END规则，或在END中应用exit语句，则终止脚本的执行。

<strong>continue示例：</strong>



<br />

awk 'BEGIN {
     for (x = 0; x <= 20; x++) {
         if (x == 5)
             continue
         printf "%d ", x
     }
     print ""
}'
--------------------------------------------------------------
awk 'BEGIN {
     x = 0
     while (x <= 20) {
         if (x == 5)
             continue
         printf "%d ", x
         x++
     }
     print ""
}'

以上代码参自<a href="https://www.gnu.org/software/gawk/manual/html_node/Continue-Statement.html" target="_blank" rel="noopener">gun gawk continue文档</a>。



<strong>break示例：</strong>



<br />

awk '{
    num = $1
    for (divisor = 2; divisor * divisor <= num; divisor++) {
        if (num % divisor == 0)
            break
    }
    if (num % divisor == 0)
        printf "Smallest divisor of %d is %d\n", num, divisor
    else
        printf "%d is prime\n", num
}'
---------------------------------------------------------------
awk '{
    num = $1
    for (divisor = 2; ; divisor++) {
        if (num % divisor == 0) {
            printf "Smallest divisor of %d is %d\n", num, divisor
            break
        }
        if (divisor * divisor > num) {
            printf "%d is prime\n", num
            break
        }
    }
}'

该部分代码参照<a href="https://www.gnu.org/software/gawk/manual/html_node/Break-Statement.html#Break-Statement" target="_blank" rel="noopener">gun soft break 文档</a>。

三、awk 脚本中运行

awk脚本也支持像shell 一样，将语句写到文件中，通过awk -f 运行，如下图：



<img src="https://www.361way.com/wp-content/uploads/2012/07/awkfile.png" width="304" height="238" alt="" />

四、性能比较

awk 求和运算



<br />

[root@361way ~]# time (awk 'BEGIN{ total=0;for(i=0;i<=10000;i++){total+=i;}print total;}')
50005000
real    0m0.003s
user    0m0.002s
sys     0m0.000s

普通的shell 求和运算



<br />

[root@361way ~]# time(total=0;for i in  $(seq 10000);do total=$ (( $total+i));done;echo$ total;)
50005000
real    0m0.145s
user    0m0.126s
sys     0m0.005s

单单从这个结果来看，同样是for循环求和，awk的性能确实数倍于普通的shell 语句。

发表回复取消回复